/* ######################### */
/* Example 1: Two Independent Samples */
/* ######################### */

DATA EX1;
INPUT TRT $ TIME;
CARDS;
tylenol 10	
tylenol 11	
tylenol 15	
tylenol 9	
advil 12
advil 16
advil 18
advil 20
;

/* Part (1) and (2): Parametric T Test */
PROC PRINT; RUN;
PROC TTEST DATA=EX1 CI=NONE; 
	CLASS TRT;
	VAR TIME;
RUN;

/* Part (3) Check Statistical Assumptions - Normality */
/* The assumption of equal variances has been checked in PROC TTEST */
PROC UNIVARIATE DATA=EX1 NORMAL PLOT;
	CLASS TRT;
	VAR TIME;
RUN;

/* Part (4) Wilcoxon Rank-Sum Test */
PROC NPAR1WAY DATA=EX1 WILCOXON;
	CLASS TRT;
	VAR TIME;
	EXACT WILCOXON;
RUN;






/* ################ */
/* Example 2: Matched Pairs */
/* ################ */

DATA EX2;
INPUT PATIENT BEFORE AFTER @@;
DIFF=BEFORE-AFTER;
CARDS;
1 210 212	2 217 210	3 208 210
4 215 213	5 202 200	6 209 208
7 207 203	8 210 199	9 221 218
10 218 214
;
PROC PRINT DATA=EX2; RUN;

/* Part (a): Construct CI for the difference */
PROC TTEST DATA=EX2 CI=NONE;
PAIRED BEFORE*AFTER;
RUN;

/* Part (b)-(c): T-Test and Wilcoxon Signed Rank-Sum Test */
PROC UNIVARIATE DATA=EX2 NORMAL PLOT;
VAR DIFF;
RUN;







/* ################################
#   EXAMPLE 3: COMPARE TWO PROPORTIONS  
################################# */

/* CONFIDENCE INTERVALS */
DATA ci2p;
	INPUT x1 n1 x2 n2 confcoeff;
	p1h = x1/n1;
	p2h = x2/n2;
	alpha = 1-confcoeff;
	zalphaover2 = PROBIT(1-alpha/2);
	diff=p1h-p2h;
	margin=zalphaover2*sqrt(p1h*(1-p1h)/n1 + p2h*(1-p2h)/n2);
	lower=diff-margin;
	upper=diff+margin;
	KEEP p1h p2h confcoeff diff margin lower upper;
	CARDS;
546 1000 475 1000 0.95
;
PROC PRINT DATA=ci2p;
RUN;



/* HYPOTHESIS TESTING */
DATA test2p;
	INPUT x1 n1 x2 n2;
	p1h = x1/n1;
	p2h = x2/n2;
	ph = (x1+x2)/(n1+n2);
	diff=p1h-p2h;
	z=(p1h-p2h)/sqrt(ph*(1-ph)/n1 + ph*(1-ph)/n2);
	pgreater = 1 - PROBNORM(z);
	pless = PROBNORM(z);
	ptwoside = 2*MIN(1-ABS(PROBNORM(z)),ABS(PROBNORM(z)));
	KEEP ph z pgreater pless ptwoside;
CARDS;
555 1500 578 1750 0
;
PROC PRINT DATA=test2p;
RUN;